单片机课程设计-99秒倒计时

课程设计指导书

合肥通用职业技术学院

电气与计算机系

二OO九年11月

单片机应用是一门很重要的专业课，它涉及到的理论及技术在工业过程控制、智能仪器仪表及家用电器中有非常广泛的应用，本课程设计的意义和目的在于：通过具体的应用实例，进一步将课本知识与实际应用融会、贯通，以达到理论与实践相结合的教学目的。

一．设计题目

99秒倒计时的设计

二．总体要求

1．仔细阅读设计任务，根据设计的任务画出硬件电路原理图

2．用汇编语言编写出相应的程序，并上机编译，纠错。

3．将程序写入单片机，在学习板中试运行。

4．写出本课程设计的实际体会。

5．完成本课程设计报告（在报告中要有设计题目、设计任务、设计要求、硬件电路图、软件程序和实际体会）

三．设计任务

用两位共阳极数码管显示一99秒倒计时时钟，要求计时时间准确，能实现动态显示。

四．系统的硬件电路原理图如下：

五．程序框图如下：

程序：                MIAO  EQU 30H

      GEWEI EQU 31H

      SHIWEI  EQU 32H

      SCANLED EQU 20H

      BUFF_1 equ 34h

      DAT1  BIT P0.6

      CLK1  BIT P0.7

      ORG 000H

      JMP START

      ORG 0BH

      JMP TIMER0

      ORG 100H

START:MOV SP,#40H

      MOV R0,#20H

      MOV R5,#20

 CLR0:MOV @R0,#00H

      INC R0

      DJNZ R5,CLR0

      MOV TMOD,#01H

      MOV TH0,#HIGH(65536-5000)

      MOV TL0,#LOW(65536-5000)

      SETB TR0

      MOV IE,#10000010B

      MOV R7,#200

      MOV P0,#0FFH

      MOV P1,#0FFH

      MOV P2,#0FFH

      MOV P3,#0FFH

      MOV MIAO,#63H

      AJMP $

TIMER0:PUSH ACC

       PUSH PSW

       MOV TH0,#HIGH(65536-5000)

       MOV TL0,#LOW(65536-5000)

       DJNZ R7,A2

       MOV  R7,#200

       MOV A,MIAO

       DEC A

       MOV MIAO,A

       CJNE A,#0FFH,A2

       MOV MIAO,#63H

   A2: MOV A,MIAO

       LCALL BIN_BCD

       MOV SHIWEI,A

       MOV GEWEI,B

       inc SCANLED

       JB SCANLED.0,SCAN_L1

SCAN_L2: mov   p0,#11011111B

         MOV   A,GEWEI

         JMP   END_SCAN

SCAN_L1: mov   p0,#11101111B

         MOV   A,SHIWEI

END_SCAN:MOV   DPTR,#TABLE

         MOVC  A,@A+DPTR

         lcall send1

         POP PSW

         POP ACC

         RETI

SEND1:  MOV   BUFF_1,#08         ;发送数据到741

          PUSH  ACC

SND1_LP:CLR   CLK1

          RLC   A

          MOV   DAT1,C

          SETB  CLK1

          DJNZ  BUFF_1,SND1_LP

          POP   ACC

          RET

 BIN_BCD:MOV  B,#10

         DIV  AB

         RET

TABLE:DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H

      END