怎样用C语言开发操作系统

尽管我的题目是“用C语言写操作系统”，但是，仅仅使用C语言是写不出操作系统的。

现代操作系统的主体部分是用C语言写的。

我是在Windows环境下开发的，而不是大多数人选择的Linux环境。开发工具也是Microsoft公司的开发工具：masm615和VC15。微软公司的masm流传甚广，大家应该不陌生。对vc15可能较陌生，vc15堪称开发DOS程序的最“高档”编译器（尽管有很多BUG）。如果实在找不到这些开发工具，使用TASM、Turbo C或者Borland C++都是可以的。所给出的例子以masm615和vc15为准，转移到TASM、TC或BC平台，应该不难。有一条原则需要注意，在这里，源码必须使用TINY模式编译，也就是说，必须生成实模式代码。

1.建立开发环境

将masm613和vc15的压缩包分别解压到e:\\masm615和e:\\msvc15目录下。你也可以放到其他目录下，根据自己的情况而定，但是下面用到的编译命令需要作相应的修改。也不需要添加或修改任何的环境变量。

2.IBM PC的启动及当时的内存使用情况

这一部分内容已经是老生常谈了，但又不能不说。我们只说从硬盘引导的情况。

当BIOS经过POST（Power On Test Self）后，将硬盘MBR读到内存0x0000:0x7C00的位置，然后从这里开始执行。一般的情况，MBR将选择活动分区进行操作系统的启动。在MBR开始执行时，内存使用的情况如下图所示，地址数据用16进制表示：

这已经是老掉牙的内容了，但是，在20年前却十分流行。如果想更详细的了解这方面的内容，找本讲解DOS的书看看吧。

我们自己的操作系统将被加载到0x1000:0x0100。这不是必需或者必然的，是人为选择的，你也可以将其放在0x4321:1234等其他地方。但是，上图中注明有其他用途的内存区域，应该保留，否则，你会后悔的。

3. 开发操作系统

我们自己的操作系统运行在实模式环境下。即使你的电脑是P4的CPU，刚启动时，也只相当于主频较高的8086而已。

首先，使用汇编语言写一个框架，文件名是entry.asm：

;

; entry.asm

;

.MODEL TINY,C

.386p

option expr32

option casemap:none

cmain PROTO NEAR C

.CODE

ORG 0100h ;偏移地址

_start:

jmp begin

nop

DB 'TianXiangYuan',0

begin:

cli

mov ax,cs

mov ds,ax

mov es,ax

mov ss,ax

mov sp,0FFFFh

sti

call cmain ;调用C语言写的主函数

mov ax,4c00h ;调用DOS的功能（为了调试），与我们自己的操作系统无关

int 21h

已经说了，操作系统将从0x1000:0x0100加载，说是无心，实则有意。我们知道，TINY模式的程序，在DOS下运行时，其起始地址就是0x0100，前面的256Byte是参数部分。如果直接将操作系统在系统启动时加载到0x1000:0x01

00，调试时非常麻烦。我们将其起始地址设为0x0100，使其可以在DOS下运行（这也是在程序的最后包含int 21h指令的原因），确认正确无误后，再进行下一步的开发。

下面再看C语言的代码，文件名是main.c：

……

static void InitShell()

{

}

void cmain()

{

InitShell();

TermShell();

}

顾名思义，其中实现了一个简单的shell。因为该程序本身是操作系统的一部分，所以，平时经常使用的一些C库函数，在这里就不能使用了。总之，一切都要自己动手实现。幸好，在实模式下，几乎所有的设备的驱动都包含在BIOS中了，我们可以直接使用。否则，连从键盘读一个键值这样的事都需要自己写键盘的驱动程序，实在太难了。也是这个原因，我们自己的操作系统没有将CPU转到保护模式下，有心之人可以试试。

下面的事情几乎都可以使用C语言实现了。

第一，初始化显示模式。系统启动时，显卡已经被初始化成3模式了，就是80X25的彩色模式（除非你的显示器是单色显示器）。当然，你也可以将显卡设成VGA甚至SVGA模式，只要你的BIOS和显卡支持。

第二，实现一个具有简单交互功能的shell。代码不全，请自己补齐。

/*

*从键盘读一个字符，如果没有输入，则等待；返回值的低字节为asii码，高字节为键盘扫描码

*/

static int getch()

{

int chr=0;

__asm

{

mov ah,00h

int 16h

mov chr,ax

}

return chr;

}

/*

*使用TTY模式向屏幕输出一个字符

*/

static void putch(unsigned char key)

{

__asm

{

mov bh,0

mov al,key

mov ah,0Eh

int 10h

}

}

#define KEY_BACKSPACE 0x08

#define KEY_ENTER 0x0D

#define KEY_NEWLINE 0x0A

#define KEY_ESCAPE 0x1B

static int printk(const char* str,...)

{

…… //给大家一点空间，自己实现吧

}

static void endline()

{

putch(KEY_NEWLINE); //Line Feed (LF)

putch(KEY_ENTER); //Enter (CR)

}

static char msg_prompt[]="CMD:";

static void deal_cmd(char* cmd_line,int cmd_len)

{

…… //也请大家自己实现吧，例如，可以实现help，dir，cls，halt等命令

…… //其实，就是字符串比较的过程

}

static void TermShell()

{

char cmd_line[80]={0,};

int cmd_len=0;

endline();

printk(msg_prompt,sizeof(msg_prompt));

for (;;)

{

cmd_line[cmd_len]=getch();

switch(cmd_line[cmd_len])

{

case KEY_ENTER:

if (cmd_len>1)

deal_cmd(cmd_line,cmd_len);

//break;

case KEY_ESCAPE:

cmd_len=0;

endline();

printk(msg_prompt,sizeof(msg_prompt));

break;

case KEY_BACKSPACE:

if (cmd_len>0)

{

putch(0x08);

putch(' ');

putch(0x08);

cmd_len--;

}

break;

default:

putch(cmd_line[cmd_len]);

cmd_len++;

}

}

}

更复杂、功能更强大的方法请参考BIOS的相关文档。说心里话，这个 “操作系统”比dos还原始！但毕竟是自己的操作系统。

4. 编译方法

下面是build.bat的内容。各种编译选项参看相关编译器的说明文档。

作系统加载到内存的0x1000:0x0100，并且cpu工作在实模式下。如果实在找不到合适的引导程序，只有自己动手写一个了。

@echo off

set PATH=e:\\masm615\\bin;e:\\msvc15\\bin;

set AS=e:\\masm615\\bin\\ml.exe

set AFLAGS=/AT /W3 /X /Gd /Zp1 /nologo

set CC=e:\\msvc15\\bin\\cl.exe

set CFLAGS=/Od /G3 /Gd /Gs /Zl /Zp1 /X /W3 /nologo

del *.obj *.com *.cod *.dbg *.pdb *.map *.lst

%AS% /c %AFLAGS% entry.asm

if errorlevel 1 goto error

%CC% /c %CFLAGS% /Fc main.c

if errorlevel 1 goto error

%AS% %AFLAGS% /Fe"boot.com" entry.obj main.obj

if errorlevel 1 goto error

goto exit

:error

echo Failure......

:exit

pause

@echo on

5. 引导程序

我们自己的操作系统虽然写完了，但是还没有办法引导，使其拥有系统的控制权。你可以使用第三方的引导程序，只要它能够将我们的操作系统加载到内存的0x1000:0x0100，并且cpu工作在实模式下。如果实在找不到合适的引导程序，只有自己动手写一个了。

;

; bootsect.asm

;

.MODEL TINY,C

.386p

option expr32

option casemap:none

SYSSEG EQU 1000h

SYSOFF EQU 0100h

.CODE

ORG 7C00h

_start:

jmp begin

nop

DB 'BOOTSECT',0 ;magic

pack_size DB 16

DB 0 ;reserved

DW 60 ;sectors

DW SYSOFF ;buf_addr_off

DW SYSSEG ;buf_addr_seg

DD 2 ;sector_from

DD 0 ;sector_from_high

begin:

cli

mov ax,cs

mov ds,ax

mov es,ax

mov ss,ax

mov sp,0FFFFh

sti

mov cx,msg_load_len ;length

lea bp,msg_load ;es:bp

call display_msg

; read disk for my OS

lea si,pack_size

mov dl,80h

mov ax,4200h

int 13h ;使用LBA方式读硬盘

jc error

; test magic of my os

lea si,magic_test ;ds:si

mov ax,SYSSEG

mov es,ax

mov di,SYSOFF

add di,3 ;es:di

mov cx,magic_test_len

cld

test_again:

cmpsb

jnz error

loop test_again

push SYSSEG

push SYSOFF

retf ;转入操作系统执行

error:

mov ax,cs

mov es,ax

lea bp,msg_error ;es:bp

mov cx,msg_error_len

call display_msg

failure:

hlt

jmp failure

;cx : length of message

;es:bp : address of message

;void display_msg();

display_msg PROC NEAR C

;scrollup a line

push cx

push bp

mov ax,0601h

mov bh,

07h

mov cx,0000h ;y/x

mov dx,184Fh ;y2/x2, 24/79

int 10h

pop bp

pop cx

;display message

mov ax,1301h

mov bx,000Ah

;mov cx,msg_error_len

mov dl,0 ;x

mov dh,24 ;y

;lea bp,msg_error ;es:bp

int 10h

ret

display_msg endp

.DATA

msg_load DB 'Loading......',0

msg_load_len DW $ - msg_load

msg_error DB 'NO BOOTER,please reboot!',0

msg_error_len DW $ - msg_error

magic_test DB 'TianXiangYuan',0

magic_test_len DW $ - magic_test

end _start

上面这段代码，是MBR的内容，他使用LBA方式读硬盘（支持大硬盘），将我们自己的操作系统读入0x1000:0x0100，然后转入操作系统执行。

很显然，我们的操作系统必须放在硬盘的No.2（LBA定位方式）扇区开始的60个扇区之内（实际上我们的操作系统远没有这么大），这时我们的引导程序的硬性规定，如果使用第三方的引导程序，也许会更方便。

可以自己开发安装程序，也可以使用WinHex工具将其写入硬盘。

这段引导程序的编译方式与操作系统一样，build.dat文件如下：

@echo off

set PATH=e:\\masm615\\bin;

set AS=e:\\masm615\\bin\\ml.exe

set AFLAGS=/AT /W3 /WX /Gd /Zp1 /X /nologo

del *.obj *.com *.cod *.dbg *.pdb *.map

%AS% /c %AFLAGS% bootsect.asm

if errorlevel 1 goto error

%AS% %AFLAGS% /Fe"bootsect.com" bootsect.obj

if errorlevel 1 goto error

goto exit

:error

echo Failure......

:exit

pause

@echo on

代码很简单的，就是进入保护模式后立即返回实模式

.386p

.model tiny,c

Desc STRUC

LimitL DW 0 ;段界限(BIT0-15)

BaseL DW 0 ;段基地址(BIT0-15)

BaseM DB 0 ;段基地址(BIT16-23)

Attributes DB 0 ;段属性

LimitH DB 0 ;段界限(BIT16-19)(含段属性的高4位)

BaseH DB 0 ;段基地址(BIT24-31)

Desc ENDS

PDesc STRUC

Limit DW 0 ;16位界限

Base DD 0 ;32位基地址

PDesc ENDS

code segment use16

assume cs:code,ds:code

org 0100h

start:

jmp begin

db 8 dup(0)

begin:

mov ax,cs

mov ds,ax

mov es,ax

mov ss,ax

mov bx,16

mul bx

mov word ptr temp_code.BaseL,ax

mov byte ptr temp_code.BaseM,dl

mov word ptr temp_data.BaseL,ax

mov byte ptr temp_data.BaseM,dl

mov bx,offset dummy

add ax,bx

adc dx,0

mov word ptr p_desc.base,ax

mov word ptr p_desc.base + 2,dx

mov ax,3000h ;这个地方我把返回dos的代码传到3000:0000的地方

mov es,ax ;就是back_dos这个子过程

mov si,offset back_dos

mov di,0

mov cx,10h

send_dos:

movsb

loop send_dos

lgdt p_desc

cli

mov eax,cr0

or eax,1

mov cr0,eax

db 0eah

dw offset init

dw temp_code_sel

init:

mov eax,cr0

and eax,0fffffffeh

mov cr0,eax

db 0eah

dw 0h

dw 3000h

back_dos proc

sti

mov ax,4c00h

int 21h;

back_dos endp

gdt label byte

dummy DESC <> ;空描述符

; 这是你原来的temp_code DESC <0ffffh,,,0h,9ah,0h>

temp_code DESC <0ffffh,,,9ah,0h,0h>

; 这是你原来的temp_data DESC <0ffffh,,,0h,92h,0h>

temp_data DESC <0ffffh,,,92h,0h,0h>

vbuf_desc DESC <0ffffh,8000h,0bh,92h,0h,0h>

gdt_len = $ - gdt

temp_code_sel = temp_code - gdt

temp_data_sel = temp_code - gdt

vbuf_sel = vbuf_desc - gdt

p_desc PDesc

data_len = $ - gdt

code ends

end start